GLE Example: join.gle

size 18 24 box	! This is JOIN.GLE, demonstrates the join commands.
set hei 1.3 just center
set font pltr
amove 9 21
text Joining named objects

set hei .8 lwidth .1
amove  8.8  18.8 
begin box name line
  rline  0 -8.2 
end box
set lwidth 0

amove  9.67745  8.7603 
begin box   name cir   nobox
  circle 1
end box
circle 1
amove  12.7461  4.59445 
begin box  name hi   add .2
  text Hi there
end box
amove  3.14401  17.0566 
begin box name grv add .2
  text GRV
end box
amove  14.9533  12.2986 
begin box name chv add .2
  text CHV
end box
amove  12.5179  17.6103 
begin box name chese add .2
  text Chese
end box
amove  2.7381  11.229 
begin box name goats add .2
  text Goats
end box
! Now draw the lines between objects
join chv - goats
join grv -> line.h          ! Note: ".h" means to join horizontally.
join line.h <-> chese.tl
join chese.tr - chv.tr
join cir.ci <- hi           ! Note: ".ci" is used for circles
join cir.ci <- chv
join cir.ci <- goats
!-----------------------------------------------------------------------------
! A pie slice
sub pie ang1 ang2 radius color$
begin path fill color$ stroke
  rmove 0 0
  arc radius ang1 ang2 
  closepath
end path
end sub
amove 3 2
@pie 0 10  2 "gray10"
@pie 10 40 2 "gray20"
@pie 40 120 2 "blue"

set hei .3 just left 
amove .3 .3 
text join.gle