GLE Example: let-multi-dim.gle


PDF file


size 21 14

amove 0 7
begin graph
   size 7 7
   let d1 = x/pi, sin(x) from -2*pi to 2*pi
   d1 line color red
end graph

amove 7 7
begin graph
   size 7 7
   let d1 = x^2, x from -2 to 2
   d1 line color red
end graph

amove 0 0
begin graph
   size 7 7
   yaxis min -3 max 3
   let d1 = log(x+1)/(6-x)*2 from -2 to 10 step 0.25
   d1 line color red
end graph

amove 7 0
begin graph
   size 7 7
   xaxis min 0 max 4
   yaxis min -7 max 7
   data "/examples/preview/let_multi_dim.csv"
   let d2 = d1+sin(6*pi*x) step 0.01
   d1 line color blue
   d2 line color red
end graph

sub entropy x
   return (-x)*log(x)/log(2)-(1-x)*log(1-x)/log(2)
end sub

amove 14 7
begin graph
   size 7 7
   title "Entropy"
   let d1 = entropy(x) from 0 to 1 where ((x < 0.125) or (x > 0.25))
   let d2 = entropy(x) from 0.125 to 0.25 step 0.125
   d1 line color red
   d2 marker square color blue
   xaxis dticks 0.25
end graph

amove 14 0
begin graph
   size 7 7
   title "yaxis max 12, xaxis max 5"
   xaxis dticks 1
   data "/examples/preview/diffstyles.csv"
   let d1 = x/2, 2*d1 where ((x <= 3) or (d1 >= 4))
   let d2 = 8 from 1.5 to 3 step 1.5
   d1 line color red
   d2 marker square color blue
end graph


return to examples page